©2024 CJDinfo®

Detalhe Solução

ASP: Formatação de Data/Hora:

'-------------------------------------------------------------------
' ConvDate
' Transforma a Data dada no formato "DD/MM/YYYY"
' ou "DD/MM/YYYY HH:MM" ou "DD/MM/YYYY HH:MM:SS"
' para o formato Date interno. A Data e Hora dadas devem corretas.
'-------------------------------------------------------------------
function ConvDate(Dado)

dim Result

Result = NULL
    if len(Dado) >= 10 then
        Result = DateSerial(mid(Dado, 7, 4), mid(Dado, 4, 2), left(Dado, 2))
        if len(Dado) = 16 then
            Result = Result + TimeSerial(mid(Dado, 12, 2), mid(Dado, 15, 2), 0)
        elseif len(Dado) = 19 then
            Result = Result + TimeSerial(mid(Dado, 12, 2), mid(Dado, 15, 2), mid(Dado, 18, 2))
        end if
    end if
    ConvDate = Result
end function

'-------------------------------------------------------------------
' StrData
' Formata a Data dada no formato "DD/MM/AAAA"
'-------------------------------------------------------------------
Function StrData(Data)

dim s

s = ""
    if IsDate(Data) then
        s = StrNum(Day(Data), 2) & "/"
        s = s & StrNum(Month(Data), 2) & "/"
        s = s & StrNum(Year(Data), 4)
    end if
    StrData = s
end function

'-------------------------------------------------------------------
' StrDataSQL
' Formata a Data dada no formato "AAAA/MM/DD"
' Retorna "NULL" se Data não válida
'-------------------------------------------------------------------
Function StrDataSQL(Data)

dim s

if IsDate(Data) then
        s = StrNum(Year(Data), 4) & "/"
        s = s & StrNum(Month(Data), 2) & "/"
        s = s & StrNum(Day(Data), 2)
    else
        s = "NULL"
    end if
    StrDataSQL = s
end function

'-------------------------------------------------------------------
' StrHora
' Formata a Data dada no formato "HH:MM:SS"
'-------------------------------------------------------------------
Function StrHora(Data)

dim s

s = ""
    if IsDate(Data) then
        s = StrNum(Hour(Data), 2) & ":"
        s = s & StrNum(Minute(Data), 2) & ":"
        s = s & StrNum(Second(Data), 2)
    end if
    StrHora = s
end function

'-------------------------------------------------------------------
' StrDataHora
' Formata a Data dada no formato "DD/MM/AAAA HH:MM:SS"
'-------------------------------------------------------------------
Function StrDataHora(Data)

StrDataHora = StrData(Data) & " " & StrHora(Data)
end function

'-------------------------------------------------------------------
' StrDataHoraSQL
' Formata a Data dada no formato "AAAA/MM/DD HH:MM:SS"
'-------------------------------------------------------------------
Function StrDataHoraSQL(Data)

StrDataHoraSQL = StrDataSQL(Data) & " " & StrHora(Data)
end function

¤ Links Relacionados:
- Veja todas as soluções do site

Gostou? Compartilhe ou comente:

Retornar